Vla-put-centermarksize

AutoLISP Home - AutoLISP 目次 - DCL - AutoLisp関数互換表 - CAD&CGブログ - オンラインショップ- GizmoTools ヘルプセンター

構文: (vla-put-centermarksize vla-object size)

機能: 半径寸法および直径寸法の中心マークのサイズを設定する。

引数

vla-object … VLAオブジェクト（DimDiametric、DimRadial、DimRadialLarge）
size … 中心マークまたは中心線のサイズを指定する正の実数。（倍精度浮動小数点数型）

戻り値: nil

MEMO:

このプロパティの初期値は 0.0900。
このプロパティは、CenterType プロパティが acCenterNone に設定されている場合は無効。
このプロパティは、指定された寸法でシステム変数 DIMCEN[中心サイズ]の値を変更する。

サンプル

(vl-load-com)
(defun c:Example_CenterMarkSize()
    ;; モデル空間に直径寸法を作成して。
    ;; 寸法の中心点種類を変更し、中心マークのサイズを調整するサンプル。
    (setq acadObj (vlax-get-acad-object))
    (setq doc (vla-get-ActiveDocument acadObj))
  
    ;; 寸法の設定
    (setq chordPoint (vlax-3d-point 5 3 0)
          farChordPoint (vlax-3d-point 5 5 0)
          leaderLength 1)
    
    ;; 直径寸法を作成
    (setq modelSpace (vla-get-ModelSpace doc))
    (setq dimObj (vla-AddDimDiametric modelSpace chordPoint farChordPoint leaderLength))
    (vla-ZoomAll acadObj)
        
    ;; 中心点のタイプとサイズを変更
    (vla-put-CenterType dimObj acCenterMark)
    (vla-put-CenterMarkSize dimObj 0.1)
    (vla-Update dimObj)
    (alert (strcat "中心マークは : " (rtos (vla-get-CenterMarkSize dimObj) 2)))
    
    (vla-put-CenterMarkSize dimObj (* (vla-get-CenterMarkSize dimObj) 2))
    (vla-Update dimObj)
    (alert (strcat "中心マークのサイズは : " (rtos (vla-get-CenterMarkSize dimObj) 2)))
)