Vla-get-patternangle

AutoLISP Home - AutoLISP 目次 - DCL - AutoLisp関数互換表 - CAD&CGブログ - オンラインショップ- GizmoTools ヘルプセンター

構文: (vla-get-patternangle vla-object )

機能: ハッチングパターンの角度を取得する。

引数

vla-object … Hatch のVLAオブジェクト

戻り値: ハッチングパターンの角度（ラジアン0～2π）

注 : このプロパティの値は、システム変数 HPANG に格納される。

サンプル

(vl-load-com)
(defun c:Example_PatternAngle()
    ;; ハッチングを作成して角度を変更するサンプル
    (setq acadObj (vlax-get-acad-object))
    (setq doc (vla-get-ActiveDocument acadObj))

    ;; ハッチの定義
    (setq patternName "ANSI31"
          patternType 0
          bAssociativity :vlax-true)
    
    ;; ハッチを作成
    (setq modelSpace (vla-get-ModelSpace doc))  
    (setq hatchObj (vla-AddHatch modelSpace patternType patternName bAssociativity acHatchObject))
    
    ;; ハッチ境界を作成
    (setq center (vlax-3d-point 5 3 0)
          radius 3
          startAngle 0
          endAngle 3.141592)

    (setq arc (vla-AddArc modelSpace center radius startAngle endAngle))
    (setq line (vla-AddLine modelSpace (vla-get-StartPoint arc) (vla-get-EndPoint arc)))
  
    (setq outerLoop (vlax-make-safearray vlax-vbObject '(0 . 1)))
    (vlax-safearray-put-element outerLoop 0 arc)
    (vlax-safearray-put-element outerLoop 1 line)
        
    ;; ハッチ境界を追加
    (vla-AppendOuterLoop hatchObj outerLoop)
    
    ;; ハッチ境界内側
    (setq center (vlax-3d-point 5 4.5 0)
          radius 1)
    (setq circle1 (vla-AddCircle modelSpace center radius))

    (setq innerLoop1 (vlax-make-safearray vlax-vbObject '(0 . 0)))
    (vlax-safearray-put-element innerLoop1 0 circle1)

    (vla-AppendInnerLoop hatchObj innerLoop1)
    
    ;; ハッチ境界内側を追加
    (setq radius 0.5)
    (setq innerLoop2 (vlax-make-safearray vlax-vbObject '(0 . 0)))
    (setq circle2 (vla-AddCircle modelSpace center radius))
    (vlax-safearray-put-element innerLoop2 0 circle2)

    (vla-AppendInnerLoop hatchObj innerLoop2)
    
    ;; ハッチ領域を算出
    (vla-Evaluate hatchObj)
    (vla-Regen doc :vlax-true)
    
    ;; ハッチ角度を取得
    (setq patternAngle (vla-get-PatternAngle hatchObj))
    (alert (strcat "ハッチパターンの角度は " (rtos (vla-get-PatternAngle hatchObj) 2)))
               
    ;; 変更
    (vla-put-PatternAngle hatchObj 5.25)
    (vla-Evaluate hatchObj)
    (vla-Regen doc :vlax-true)
    (alert (strcat "新しいハッチ角度は " (rtos (vla-get-PatternAngle hatchObj) 2)))
)