Vla-put-promptstring

AutoLISP Home - AutoLISP 目次 - DCL - AutoLisp関数互換表 - CAD&CGブログ - オンラインショップ- GizmoTools ヘルプセンター

構文: (vla-put-promptstring vla-object PromptString')

機能: 属性の入力を求めるプロンプト文字列を指定する。

引数

vla-object … Attribute の VLA オブジェクト
PromptString… プロンプト文字列

戻り値: nil

サンプル

(vl-load-com)
(defun c:Example_PromptString()
    ;; 属性付きブロックを作成して挿入し、
    ;; 属性定義のプロンプト文字列を変更してから、
    ;; 再度ブロックを挿入するサンプル。
    (setq acadObj (vlax-get-acad-object))
    (setq doc (vla-get-ActiveDocument acadObj))

    ;; ブロック作成
    (setq insertionPnt (vlax-3d-point 0 0 0))
    (setq blockObj (vla-Add (vla-get-Blocks doc) insertionPnt "TEST"))
    
    ;; ブロックに円を追加
    (setq center (vlax-3d-point 0 0 0)
          radius 1)
    (setq circleObj (vla-AddCircle blockObj center radius))

    ;; 属性の設定
    (setq insertionPoint (vlax-3d-point 0 0 0) 
          attHeight 1
          attMode acAttributeModeVerify
          attPrompt "値を入力 :"
          attTag "Tag1"
          attValue "Circle1")
    
    ;; 属性を作成
    (setq attributeObj (vla-AddAttribute blockObj attHeight attMode attPrompt insertionPoint attTag attValue))
    
    ;; ブロックを挿入
    (setq insertionPnt (vlax-3d-point 2 2 0))
    (setq modelSpace (vla-get-ModelSpace doc))
    (setq blockRefObj1 (vla-InsertBlock modelSpace insertionPnt "TEST" 1 1 1 0))
        
    ;; 属性のプロンプト文字列を変更
    (vla-put-PromptString attributeObj "値を確認 :")
    
    ;; ブロックを再度挿入
    (setq insertionPnt (vlax-3d-point 4 4 0))
    (setq modelSpace (vla-get-ModelSpace doc))
    (setq blockRefObj2 (vla-InsertBlock modelSpace insertionPnt "TEST" 1 1 1 0))
    
    (vla-ZoomAll acadObj)
)