Vla-put-patterndouble

AutoLISP Home - AutoLISP 目次 - DCL - AutoLisp関数互換表 - CAD&CGブログ - オンラインショップ- GizmoTools ヘルプセンター

構文: (vla-put-patterndouble vla-object bool )

機能: ユーザ定義ハッチングがダブルハッチングかどうかを指定する。

引数

vla-object … Hatch のVLAオブジェクト
bool … ブール型

:vlax-True: ダブルハッチングパターンを使用する。
:vlax-False: ダブルハッチングパターンを使用しない。

戻り値: nil

MEMO : PatternType プロパティが acHatchPatternTypePreDefined または acHatchPatternTypeCustomDefined に設定されている場合、PatternDouble プロパティは使用されない。

注 : このプロパティの値は、システム変数 HPDOUBLE に格納されます。

サンプル

(vl-load-com)
(defun c:Example_patterndouble()
    ;; ハッチングを作成してパターンダブルを変更するサンプル
    (setq acadObj (vlax-get-acad-object))
    (setq doc (vla-get-ActiveDocument acadObj))

    ;; ハッチの定義
    (setq patternName "ANSI31"
          patternType 0
          bAssociativity :vlax-true)
    
    ;; ハッチを作成
    (setq modelSpace (vla-get-ModelSpace doc))  
    (setq hatchObj (vla-AddHatch modelSpace patternType patternName bAssociativity acHatchObject))
    
    ;; ハッチ境界を作成
    (setq center (vlax-3d-point 5 3 0)
          radius 3
          startAngle 0
          endAngle 3.141592)

    (setq arc (vla-AddArc modelSpace center radius startAngle endAngle))
    (setq line (vla-AddLine modelSpace (vla-get-StartPoint arc) (vla-get-EndPoint arc)))
  
    (setq outerLoop (vlax-make-safearray vlax-vbObject '(0 . 1)))
    (vlax-safearray-put-element outerLoop 0 arc)
    (vlax-safearray-put-element outerLoop 1 line)
        
    ;; ハッチ境界を追加
    (vla-AppendOuterLoop hatchObj outerLoop)
    
    ;; ハッチ境界内側
    (setq center (vlax-3d-point 5 4.5 0)
          radius 1)
    (setq circle1 (vla-AddCircle modelSpace center radius))

    (setq innerLoop1 (vlax-make-safearray vlax-vbObject '(0 . 0)))
    (vlax-safearray-put-element innerLoop1 0 circle1)

    (vla-AppendInnerLoop hatchObj innerLoop1)
    
    ;; ハッチ境界内側を追加
    (setq radius 0.5)
    (setq innerLoop2 (vlax-make-safearray vlax-vbObject '(0 . 0)))
    (setq circle2 (vla-AddCircle modelSpace center radius))
    (vlax-safearray-put-element innerLoop2 0 circle2)

    (vla-AppendInnerLoop hatchObj innerLoop2)
    
    ;; ハッチ領域を算出
    (vla-Evaluate hatchObj)
    (vla-Regen doc :vlax-true)
    
    ;; パターンダブルの設定を取得
    (setq patternDouble (vla-get-PatternDouble hatchObj))
    (alert (strcat "現在のパターンダブルの設定は : " (if (= patternDouble :vlax-true) "True" "False")))
               
    ;; 変更
    (vla-put-PatternDouble hatchObj (if (= patternDouble :vlax-true) :vlax-false :vlax-true))
    (vla-Evaluate hatchObj)
    (vla-Regen doc :vlax-true)
    (alert (strcat "新しいパターンダブルの設定は : " (if (= (vla-get-PatternDouble hatchObj) :vlax-true) "True" "False")))

)