Vla-put-hatchstyle

AutoLISP Home - AutoLISP 目次 - DCL - AutoLisp関数互換表 - CAD&CGブログ - オンラインショップ- GizmoTools ヘルプセンター

構文: (vla-put-hatchstyle vla-object style)

機能: ハッチングスタイルを指定する。

引数

vla-object … Hatch の VLAオブジェクト
style … acHatchStyle 列挙型

acHatchStyleNormal ：標準スタイル。このスタイルは、外側境界線の内側をハッチングする。CAD は内側にある境界に達すると、さらに内側の境界を見つけるまでハッチングをオフにする。
acHatchStyleOuter ：外側領域のみを塗り潰す。このスタイルは、領域境界線から内側もハッチングするが、内部境界線を検出するとハッチングをオフにし、再びオンにすることはない。
acHatchStyleIgnore ：内部構造を無視する。このオプションはすべての内部オブジェクトをハッチングする。（島検出なし）

戻り値: nil

サンプル

(vl-load-com)
(defun c:Example_HatchStyle()
    ;; 異尺度ハッチを作成するサンプル
    ;; ハッチスタイルを変更するデモ
    (setq acadObj (vlax-get-acad-object))
    (setq doc (vla-get-ActiveDocument acadObj))
  
    ;; ハッチの定義
    (setq patternName "ANSI31"
          patternType 0
          bAssociativity :vlax-true)
    
    ;; 異尺度ハッチを作成
    (setq modelSpace (vla-get-ModelSpace doc))  
    (setq hatchObj (vla-AddHatch modelSpace patternType patternName bAssociativity acHatchObject))
    
    ;; ハッチ用の境界図形作成 閉じた図形になっている
    (setq center (vlax-3d-point 5 3 0)  
          radius 3
          startAngle 0
          endAngle 3.141592)

    (setq arc (vla-AddArc modelSpace center radius startAngle endAngle))
    (setq line (vla-AddLine modelSpace (vla-get-StartPoint arc) (vla-get-EndPoint arc)))
  
    (setq outerLoop (vlax-make-safearray vlax-vbObject '(0 . 1)))
    (vlax-safearray-put-element outerLoop 0 arc)
    (vlax-safearray-put-element outerLoop 1 line)
        
    ;; ハッチングオブジェクトに外側のループを追加して、ハッチを表示
    (vla-AppendOuterLoop hatchObj outerLoop)

    ;; ハッチの内側のループとしての円を追加
    (setq center (vlax-3d-point 5 4.5 0))  
    (setq radius 1)
    (setq circle1 (vla-AddCircle modelSpace center radius))

    (setq innerLoop1 (vlax-make-safearray vlax-vbObject '(0 . 0)))
    (vlax-safearray-put-element innerLoop1 0 circle1)

    (vla-AppendInnerLoop hatchObj innerLoop1)
  
    ;; 他の内側のループとして第2の円を追加
    (setq radius 0.5)
    (setq innerLoop2 (vlax-make-safearray vlax-vbObject '(0 . 0)))
    (setq circle2 (vla-AddCircle modelSpace center radius))
    (vlax-safearray-put-element innerLoop2 0 circle2)

    (vla-AppendInnerLoop hatchObj innerLoop2)
    (vla-ZoomAll acadObj)
    
    ;; ノーマルスタイルのハッチ
    (vla-put-hatchstyle hatchObj acHatchStyleNormal)
    (vla-Evaluate hatchObj)
    (vla-Regen doc :vlax-true)
    (alert (strcat "ハッチスタイルを設定 "
                   (cond
                     ((= (vla-get-hatchstyle hatchObj) 0) "acHatchStyleNormal")
                     ((= (vla-get-hatchstyle hatchObj) 1) "acHatchStyleOuter")
                     ((= (vla-get-hatchstyle hatchObj) 2) "acHatchStyleIgnore")
                   )))
    
    ;; アウタースタイルのハッチ
    (vla-put-hatchstyle hatchObj acHatchStyleOuter)
    (vla-Evaluate hatchObj)
    (vla-Regen doc :vlax-true)
    (alert (strcat "ハッチスタイルを設定 "
                   (cond
                     ((= (vla-get-hatchstyle hatchObj) 0) "acHatchStyleNormal")
                     ((= (vla-get-hatchstyle hatchObj) 1) "acHatchStyleOuter")
                     ((= (vla-get-hatchstyle hatchObj) 2) "acHatchStyleIgnore")
                   )))
        
    ;; 島なしスタイルのハッチ
    (vla-put-hatchstyle hatchObj acHatchStyleIgnore)
    (vla-Evaluate hatchObj)
    (vla-Regen doc :vlax-true)
    (alert (strcat "ハッチスタイルを設定 "
                   (cond
                     ((= (vla-get-hatchstyle hatchObj) 0) "acHatchStyleNormal")
                     ((= (vla-get-hatchstyle hatchObj) 1) "acHatchStyleOuter")
                     ((= (vla-get-hatchstyle hatchObj) 2) "acHatchStyleIgnore")
                   )))
)