Vla-put-clippingenabled

AutoLISP Home - AutoLISP 目次 - DCL - AutoLisp関数互換表 - CAD&CGブログ - オンラインショップ- GizmoTools ヘルプセンター

構文: (vla-put-clippingenabled vla-object bool ' ')

機能: クリップ境界のオン/オフを設定する。

引数

vla-object … VLAオブジェクト（DgnUnderlay、DwfUnderlay、GeomapImage、PdfUnderlay、RasterImage、Wipeout）
bool … ブール値

Vlax-True : クリップ境界を有効する。
Vlax-False : クリップ境界を無効にする。

注意

クリップ境界を使用すると、クリッピングされたイメージまたはアンダーレイを表示することができる。
クリップ境界を非表示にして元のイメージまたはアンダーレイの境界を表示することもできる。
クリップ境界を設定するには、vla-clipboundary を使用する。

戻り値: nil

サンプル

(vl-load-com)
(defun c:Example_ClipBoundary()
    ;; モデル空間でラスター イメージを追加し、クリップ境界に基づいて
    ;; 画像を切り取るサンプル
    (setq acadObj (vlax-get-acad-object))
    (setq doc (vla-get-ActiveDocument acadObj))
  
    ;; サンプル ディレクトリにある "2d Projected Polylines.jpg"を使用する。
    ;; ファイルの場所は imageName 変数で調整
    (setq insertionPoint (vlax-3d-point 5 5 0)
          imageName ".\\Sample\\VISP\\2d Projected Polylines.jpg"
          scalefactor 2
          rotationAngle 0)

    (if (/= (findfile ".\\Sample\\VISP\\2d Projected Polylines.jpg") nil)
        (progn  
	    ;; モデルにラスターを配置
            (setq modelSpace (vla-get-ModelSpace doc))
            (setq rasterObj (vla-AddRaster modelSpace (findfile ".\\Sample\\VISP\\2d Projected Polylines.jpg") insertionPoint scalefactor rotationAngle))
    
	    (vla-ZoomAll acadObj)
	    (alert "イメージをクリップ？")
	    
	    ;; クリップ境界の設定
	    (setq clipPoints (vlax-make-safearray vlax-vbDouble '(0 . 9)))
	    (vlax-safearray-fill clipPoints '(6 6.75
                                              7 6
                                              6 5
                                              5 6
                                              6 6.75
                                             )
            )
	    
	    ;; イメージのクリップ
	    (vla-ClipBoundary rasterObj clipPoints)
	    
	    ;; クリップの表示を有効に
	    (vla-put-ClippingEnabled rasterObj :vlax-true)
	    (vla-Regen doc acActiveViewport)
	    (alert "クリップを有効にしますた")
        )
        (alert (strcat imageName " がないっす。"))
    )    
)