Vla-get-patternspace

AutoLISP Home - AutoLISP 目次 - DCL - AutoLisp関数互換表 - CAD&CGブログ - オンラインショップ- GizmoTools ヘルプセンター

構文: (vla-get-patternspacevla-object)

機能: ユーザ定義ハッチングパターンの間隔を取得する。

引数

vla-object … Hatch のVLAオブジェクト

戻り値: ハッチングパターンの間隔。

MEMO : PatternType プロパティが acHatchPatternTypePreDefined または acHatchPatternTypeCustomDefined に設定されている場合、PatternSpace プロパティは使用されない。
注 : このプロパティの値は、システム変数 HPSPACE に格納される。

サンプル

(vl-load-com)
(defun c:Example_patternspace()
    ;; ハッチングを作成してパターンダブルを変更するサンプル
    (setq acadObj (vlax-get-acad-object))
    (setq doc (vla-get-ActiveDocument acadObj))

    ;; ハッチの定義
    (setq patternName "ANSI31"
          patternType 0
          bAssociativity :vlax-true)
    
    ;; ハッチを作成
    (setq modelSpace (vla-get-ModelSpace doc))  
    (setq hatchObj (vla-AddHatch modelSpace patternType patternName bAssociativity acHatchObject))
    
    ;; ハッチ境界を作成
    (setq center (vlax-3d-point 5 3 0)
          radius 3
          startAngle 0
          endAngle 3.141592)

    (setq arc (vla-AddArc modelSpace center radius startAngle endAngle))
    (setq line (vla-AddLine modelSpace (vla-get-StartPoint arc) (vla-get-EndPoint arc)))
  
    (setq outerLoop (vlax-make-safearray vlax-vbObject '(0 . 1)))
    (vlax-safearray-put-element outerLoop 0 arc)
    (vlax-safearray-put-element outerLoop 1 line)
        
    ;; ハッチ境界を追加
    (vla-AppendOuterLoop hatchObj outerLoop)
    
    ;; ハッチ境界内側
    (setq center (vlax-3d-point 5 4.5 0)
          radius 1)
    (setq circle1 (vla-AddCircle modelSpace center radius))

    (setq innerLoop1 (vlax-make-safearray vlax-vbObject '(0 . 0)))
    (vlax-safearray-put-element innerLoop1 0 circle1)

    (vla-AppendInnerLoop hatchObj innerLoop1)
    
    ;; ハッチ境界内側を追加
    (setq radius 0.5)
    (setq innerLoop2 (vlax-make-safearray vlax-vbObject '(0 . 0)))
    (setq circle2 (vla-AddCircle modelSpace center radius))
    (vlax-safearray-put-element innerLoop2 0 circle2)

    (vla-AppendInnerLoop hatchObj innerLoop2)
    
    ;; ハッチ領域を算出
    (vla-Evaluate hatchObj)
    (vla-Regen doc :vlax-true)
    
    ;; ハッチ間隔を取得
    (setq patternSpace (vla-get-PatternSpace hatchObj))
    (alert (strcat "現在のハッチ間隔は " (rtos patternSpace 2)))
                  
    ;; 変更
    (vla-put-PatternSpace hatchObj (+ patternSpace 2))
    (vla-Evaluate hatchObj)
    (vla-Regen doc :vlax-true)
    (alert (strcat "新しいハッチ間隔は " (rtos (vla-get-PatternSpace hatchObj) 2)))

)