Vla-get-altsuppresstrailingzeros

AutoLISP Home - AutoLISP 目次 - DCL - AutoLisp関数互換表 - CAD&CGブログ - オンラインショップ- GizmoTools ヘルプセンター

構文: (vla-get-altsuppresstrailingzeros vla-object bool )

機能: 変換単位寸法値の末尾のゼロの表示の省略を取得する。

引数

vla-object … VLAオブジェクト（DimAligned、DimArcLength、DimDiametric、DimOrdinate、DimRadial、DimRadialLarge、DimRotated）

戻り値

ブール型

:vlax-True: 変換単位寸法値の末尾のゼロを表示しない。たとえば、0.5000 は 0.5 になる。
:vlax-False: 変換単位寸法値の末尾のゼロを表示する。

MEMO：このプロパティの初期値は False 。
注 : このプロパティは、指定された寸法でシステム変数 DIMALTZ[併記寸法 0 省略]の値を変更する。

サンプル

(vl-load-com)
(defun c:Example_AltRoundDistance()
    ;; 寸法を作成して、変換単位寸法許容差値の接頭の
    ;; ゼロ表示の省略の設定を変更するサンプル
    (setq acadObj (vlax-get-acad-object))
    (setq doc (vla-get-ActiveDocument acadObj))
  
    ;; 寸法の定義
    (setq point1 (vlax-3d-point 5 5 0)
          point2 (vlax-3d-point 10.123 5 0)
          location (vlax-3d-point 5 7 0))

    ;; 寸法をモデルに作成
    (setq modelSpace (vla-get-ModelSpace doc))
    (setq dimObj (vla-AddDimAligned modelSpace point1 point2 location))
        
    ;; 代替単位を表示に設定
    (setq originalValue (vla-get-altsuppresstrailingzeros dimObj))
    (vla-put-AltUnits dimObj :vlax-true)
    
    (vla-ZoomAll acadObj)
    (vla-Regen doc acAllViewports)

    (alert "別単位の末尾ゼロ表示を切り替えます。")
    
    ;; ゼロ表示をトグルで切り替え
    (vla-put-altsuppresstrailingzeros dimObj (if (= originalValue :vlax-true) :vlax-false :vlax-true))
    (setq newValue (vla-get-altsuppresstrailingzeros dimObj))

    (vla-Regen doc acAllViewports)
    
    (alert "別単位の末尾ゼロ表示を元に戻します")

    (vla-put-altsuppresstrailingzeros dimObj (if (= newValue :vlax-true) :vlax-false :vlax-true))  
    (vla-Regen doc acAllViewports)
)