Vla-zoompickwindow

AutoLISP Home - AutoLISP 目次 - DCL - AutoLisp関数互換表 - CAD&CGブログ - オンラインショップ- GizmoTools ヘルプセンター

構文: (vla-zoompickwindow vla-object)

機能: 現在のビューポートを画面上のクリックされた点によって定義されるウィンドウにズームする。

引数

vla-object … application

戻り値: nil

このメソッドは、現在のアクティブなビューポート(ペーパー空間ビューポートまたはモデル空間ビューポート)にのみ適用される。

サンプル

(vl-load-com)
(defun c:Example_ZoomAll()
    ;; ズームオプション色々のサンプル
    (setq acadObj (vlax-get-acad-object))
    (setq doc (vla-get-ActiveDocument acadObj))
    (setq modelSpace (vla-get-ModelSpace doc))

    ;; 放射線を作成
    (setq basePoint (vlax-3d-point 3 3 0)
          secondPoint (vlax-3d-point 1 3 0))
    (setq rayObj (vla-AddRay modelSpace basePoint secondPoint))
    
    ;; ポリラインを作成
    (setq points (vlax-make-safearray vlax-vbDouble '(0 . 5)))
    (vlax-safearray-fill points '(3 7
                                  9 2
                                  3 5))
    (setq plineObj (vla-AddLightWeightPolyline modelSpace points))
    (vla-put-Closed plineObj :vlax-true)

    ;; 線分を作成
    (setq startPoint (vlax-3d-point 0 0 0)
          endPoint (vlax-3d-point 2 2 0))
    (setq lineObj (vla-AddLine modelSpace startPoint endPoint))
    
    ;; 円を作成
    (setq centerPt (vlax-3d-point 20 30 0)
          radius 3)
    (setq circObj (vla-AddCircle modelSpace centerPt radius))

    ;; 楕円を作成
    (setq center (vlax-3d-point 5 5 0)
          majAxis (vlax-3d-point 10 20 0)
          radRatio 0.3)
    (setq ellObj (vla-AddEllipse modelSpace center majAxis radRatio))

;; ZoomAll
    (alert "Perform a ZoomAll")
    (vla-ZoomAll acadObj)
    
;; ZoomWindow
    (alert (Strcat "Perform a ZoomWindow using the following coordinates:"
                   "\n1.3, 7.8, 0"
                   "\n13.7, -2.6, 0"))

    (setq point1 (vlax-3d-point 1.3 7.8 0)
          point2 (vlax-3d-point 13.7 -2.6 0))
    (vla-ZoomWindow acadObj point1 point2)
    
;; ZoomScaled
    (alert (strcat "Perform a ZoomScaled using:"
                   "\nScale Type: acZoomScaledRelative"
                   "\nScale Factor: 2"))
    (setq scalefactor 2
          scaletype acZoomScaledRelative)
    (vla-ZoomScaled acadObj scalefactor scaletype)
    
;; ZoomExtents
    (alert "Perform a ZoomExtents")
    (vla-ZoomExtents acadObj)
    
;; ZoomPickWindow
    (alert "Perform a ZoomPickWindow")
    (vla-ZoomPickWindow acadObj)

;; ZoomPrevious
    (alert "Perform a ZoomPrevious")
    (vla-ZoomPrevious acadObj)

;; ZoomCenter
    (alert (strcat "Perform a ZoomCenter using:"
                   "\nCenter 3, 3, 0"
                   "\nMagnification: 10"))

    (setq zcenter (vlax-3d-point 3 3 0)
          magnification 10)
    (vla-ZoomCenter acadObj zcenter magnification)
)